Enviando e-mails com VBscript e SMTP do Gmail

Bom dia galera,segue um script para enviar e-mails de possíveis alertas
do seu Rwindows ou vai da sua imaginação, hehehe.

on error resume next

Const schema   = "http://schemas.microsoft.com/cdo/configuration/"
Const cdoBasic = 1
Const cdoSendUsingPort = 2
Dim oMsg, oConf

' Propriedades do email
Set oMsg      = CreateObject("CDO.Message")
oMsg.From     = "pablogomezcorrea@gmail.com" ' ou "Nome do remetente "
oMsg.To       = "teste@destino.com.br"       ' ou "Nome do destino "
oMsg.Subject  = "Teste de VBscript"
oMsg.TextBody = "Mensagem enviada com sucesso !!! Enjoy it"

' Configuração e autenticação do seu servidor de SMTP Gmail
Set oConf = oMsg.Configuration

'Endereço do servidor de SMTP
oConf.Fields(schema & "smtpserver")       = "smtp.gmail.com"

'Número da porta
oConf.Fields(schema & "smtpserverport")   = 465

oConf.Fields(schema & "sendusing")        = cdoSendUsingPort

'Tipo de autenticacao
oConf.Fields(schema & "smtpauthenticate") = cdoBasic

'Uso da Encriptação SSL
oConf.Fields(schema & "smtpusessl")       = True

'Envia username
oConf.Fields(schema & "sendusername")     = "pablogomezcorrea@gmail.com"

'Envia password
oConf.Fields(schema & "sendpassword")     = "12345678"

oConf.Fields.Update()

' Envia mensagem
oMsg.Send()

' Retorna o status da mensagem
If Err Then
    resultMessage = "ERROR " & Err.Number & ": " & Err.Description
    Err.Clear()
Else
    resultMessage = "Mensagem enviada com sucesso !!!"
End If

Wscript.echo(resultMessage)